ATtiny 11 Hex File And Source Code

Hans Krobath

ED Online ID #19849

February 16, 2006

Article Rating: Not Rated

Hex Code for ATtiny 11:

Untitled Document

:020000020000FC

:1000000005C004C003C002C001C000C00CE108BBB1

:100010000CE107BB00E408B911240024B59BFCCF18

:1000200000000A94D9F71A94C9F7B599FECFC3987E

:10003000000000000000C39A08E08894B09908947A

:100040001795C298000000000000C29A0A95A9F70F

:10005000000021E0B09922E033240AD009D008D072

:10006000C49806D01A95E9F72A95D9F7C49AD4CF3F

:1000700043E03327332041F44599FACF3A95E1F72D

:100080004A95D1F730940895459BF2CF3A95E1F720

:080090004A95D1F73094089560

:00000001FF

ATtiny 11 Source Code:

Untitled Document

; INTPWRB.ASM INTERRUPT POWER FOR SET NO. OF HALF 60 HZ

; MPU ATTINY11-6

.NOLIST

.INCLUDE "TN11DEF.INC

.LIST

;

; INTERNAL RC OSCILLATOR TCYC = 1 USEC

;

; FLASH FUSE BITS;

; FRST = U STANDARD START UP TIME

; RSTDISBL = P RESET PIN USED AS INPUT

; CKSEL2 = U

; CKSEL1 = P

; CKSEL0 = P USE INTERNAL 1MHZ RC OSCILLATOR

;

.EQU SWD = 0 ;PORTB PB0 PIN 5 INPUT - SERIAL SW DAT

.EQU ANI = 1 ;PORTB PB1 PIN 6 INPUT ANI1 (USING INT VREF)

.EQU SCK = 2 ;PORTB PB2 PIN 7 OUTPUT - SHIFT CLOCK

.EQU LDL = 3 ;PORTB PB5 PIN 2 OUTPUT - SERIAL SW LOAD LO

.EQU KON = 4 ;PORTB PB4 PIN 3 OUTPUT - SSR HI ON

.EQU STR = 5 ;PORTB PB5 PIN 1 INPUT - START SW

;

.CSEG

.ORG 0X000

RJMP RESET

RJMP RESET ;EINT0

RJMP RESET ;PIN CHG

RJMP RESET ;TMR0

RJMP RESET ;EE RDY

RJMP RESET ;ANA CMP

RESET:

LDI R16,$1C ;INIT OUTPUTS PB3 TO HI

OUT PORTB,R16

LDI R16,$1C ;PB1 INPUT

OUT DDRB,R16 ;INIT PB2,3,4 AS OUTPUTS

;

LDI R16,$40

OUT ACSR,R16 ;ANA COMP W/INT REF

;

WSWH: CLR R1 ;WAIT FOR STEADY HI FOR 400MSEC OF STR SW

CLR R0

LLA: SBIS PINB,STR

RJMP WSWH

NOP

DEC R0

BRNE LLA

DEC R1

BRNE LLA

;

WSL: SBIC PINB,STR ;WAIT FOR SW STR = LO

RJMP WSL

;

CBI PORTB,LDL

NOP

SBI PORTB,LDL ;LOAD SHIFT REG

;

LDI R16,8

LSW: CLC

SBIC PINB,SWD

SEC

ROR R17

CBI PORTB,SCK

NOP

SBI PORTB,SCK

DEC R16

BRNE LSW ;SHIFT IN R17 8X

NOP

LDI R18,$01

SBIC PINB,SWD ;SET R18

LDI R18,$02

CLR R3 ;INIT WSHL TOGGLE FLAG

RCALL WSHL

CBI PORTB,KON ;SSR ON

LLCT: RCALL WSHL

DEC R17

BRNE LLCT

DEC R18

BRNE LLCT

SBI PORTB,KON ;SSR OFF

RJMP WSWH ;RESTART

;

; WAIT FOR ACO STEADY LO (R3=$00) OR STEADY HI (R3=$FF)

WSHL:

LDI R20,3

CLR R19

TST R3

BRNE WS1

WS0: SBIC ACSR,ACO

RJMP WSHL

DEC R19

BRNE WS0

DEC R20

BRNE WS0

COM R3

RET

WS1:

SBIS ACSR,ACO

RJMP WSHL

DEC R19

BRNE WS1

DEC R20

BRNE WS1

COM R3

RET

;

.EXIT